LEGEND引擎玩家坐庄脚本
很多传奇GM都非常头疼赌博脚本，但是作为一个娱乐性较强的版本，坐庄脚本算是一个不可或缺的部分了。今天我们专门为大家提供了一个现成的玩家坐庄脚本可供大家直接下载使用。使用本脚本需注意三点：1、首先需要确认StartQuest的文字命令为：开始提问。否则将无法执行完整脚本段。2、确认调整人物元宝的命令为：调整元宝。否则玩家庄被抢了以后无法返还到元宝！3、检查版本内使用的变量是否和抢庄脚本变量有冲突。当然对于传奇私服新手GM来说，这将会是一个难点。如果前期不会检查，那就只能加上去以后再检查是否正常了！
NPC脚本预览：
(@@InPutInteger)
[@MAIN]
#if
ISONMAP T140LS
#ELSEACT
CLOSE
BREAK
#if
EQUAL M45 0
#act
mov S10 你还没有下注，请赶快下注。
#elseact
mov S10 你下注【
inc S10 <$STR(M43)>
inc S10 】元宝押【
INC S10 <$STR(S23)>
INC S10 】
#if
large G8 70
#act
mov S10 正在坐庄，你可以进行抢庄。
#if
EQUAL M45 0
EQUAL A34 <$USERNAME>
#act
mov S10 你是庄家，请等待开局。
#if
small G8 70
equal G29 0
#act
mov S10 无人坐庄，请等下一局。
#if
small G8 10
#act
mov S10 正在开点，请等待结果。
#if
small G8 5
#act
mov S10 本局开点结果为：【
INC S10 <$STR(A15)>
INC S10 】
#if
small G8 2
#act
mov S10 正在结算清零，新局开始
#if
equal M1 1
#say
欢迎光临，这里是猜点数游戏，你所拥有的元宝：【<$GAMEGOLD>】\
庄家姓名：【<$STR(A34)>】 庄家本钱数：【<$STR(G29)>】\
╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗\
┊<查看说明/@Help>┊┊<开始坐庄/@@InPutInteger40>┊┊<下注押大/@@InPutInteger41>┊┊<下注押小/@@InPutInteger42>┊┊<返回盟重/@Over>┊\
╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝\
押大总金额：【<$STR(G13)>】 押小总金额：【<$STR(G14)>】 剩余时间：<$STR(G8)>\
你的下注情况：<$STR(S10)> <停止刷新/@stopmain>\
#act
delaygoto 1000 @main
#elsesay
欢迎光临，这里是猜点数游戏，你所拥有的元宝：【<$GAMEGOLD>】\
庄家姓名：【<$STR(A34)>】 庄家本钱数：【<$STR(G29)>】\
╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗\
┊<查看说明/@Help>┊┊<开始坐庄/@@InPutInteger40>┊┊<下注押大/@@InPutInteger41>┊┊<下注押小/@@InPutInteger42>┊┊<返回盟重/@Over>┊\
╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝\
押大总金额：【<$STR(G13)>】 押小总金额：【<$STR(G14)>】 剩余时间：<$STR(G8)>\
你的下注情况：<$STR(S10)> <自动刷新/@automain>\
[@automain]
#if
#act
mov M1 1
goto @main
[@stopmain]
#if
#act
mov M1 0
goto @main
[@@InPutInteger40]
#If
CheckLevelEx > 0
#Act
DelayGoto 1 ~InPutInteger40
[~InPutInteger40]
#IF
LARGE G12 60
#ACT
MESSAGEBOX [提示]：抢庄时间已经结束。请等待开局！
MOV M40 0
GOTO @MAIN
BREAK
#IF
SMALL M40 100
#ACT
MESSAGEBOX [提示]：请输入100以上的数值！
MOV M40 0
GOTO @MAIN
BREAK
#IF
large M40 50000
#ACT
MESSAGEBOX [提示]：请输入50000以下的数值！
MOV M40 0
GOTO @MAIN
BREAK
#IF
EQUAL A34 <$USERNAME>
#ACT
MOV M40 0
MESSAGEBOX [提示]：你目前已经是庄家，无法重复坐庄。
GOTO @MAIN
BREAK
#IF
EQUAL M45 2
#ACT
MOV M40 0
MESSAGEBOX [提示]：你已经下注押了大，无法坐庄！
GOTO @MAIN
BREAK
#IF
EQUAL M45 3
#ACT
MOV M40 0
MESSAGEBOX [提示]：你已经下注押了小，无法坐庄！
GOTO @MAIN
BREAK
#IF
CHECKGAMEGOLD < <$STR(M40)>
#ACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV M40 0
GOTO @MAIN
BREAK
#IF
LARGE M40 <$STR(G29)>
#ACT
goto @庄家检测在线
GAMEGOLD - <$STR(M40)>
MOV G29 <$STR(M40)>
SendMSG 1 %s使用<$STR(M40)>个元宝坐庄。
MOV A34 <$USERNAME>
GOTO @MAIN
MESSAGEBOX [提示]：使用【<$STR(M40)>】个元宝坐庄。
BREAK
#ELSEACT
MESSAGEBOX [提示]：你必须出多于【<$STR(G29)>】个元宝才能抢庄。
MOV M40 0
GOTO @MAIN
BREAK
[@庄家检测在线]
#if
equal A34
#act
break
#if
equal A34 无
#act
break
#elseact
gmexecute 调整元宝 <$STR(A34)> + <$STR(G29)>
break
[@@InPutInteger41]
#If
CheckLevelEx > 0
#Act
MOVR M62 4
INC M62 2
DelayGoto 1 ~InPutInteger41
[~InPutInteger41]
#IF
LARGE G12 120
#ACT
MESSAGEBOX [提示]：下注时间已经结束。请等待开局！
MOV M41 0
GOTO @MAIN
BREAK
#IF
SMALL G12 61
#ACT
MESSAGEBOX [提示]：下注时间还没到，现在是抢庄时间。
MOV M41 0
GOTO @MAIN
BREAK
#IF
SMALL M41 10
#ACT
MESSAGEBOX [提示]：请输入10以上的数值！
MOV M41 0
GOTO @MAIN
BREAK
#IF
EQUAL A34 <$USERNAME>
#ACT
MOV M40 0
MESSAGEBOX [提示]：你目前已经是庄家，无法重复坐庄。
GOTO @MAIN
BREAK
#IF
EQUAL M45 2
#ACT
MOV M41 0
MESSAGEBOX [提示]：你已经下注押了大，无法重复下注！
GOTO @MAIN
BREAK
#IF
EQUAL M45 3
#ACT
MOV M41 0
MESSAGEBOX [提示]：你已经下注押了小，无法重复下注！
GOTO @MAIN
BREAK
#IF
LARGE M41 <$STR(G9)>
#ACT
MOV M41 0
MESSAGEBOX [提示]：对不起，庄家的本钱已达到上限不够赔了。\ \目前你只可以下注【<$STR(G9)>】以下的元宝！
GOTO @MAIN
BREAK
#IF
CHECKGAMEGOLD > <$STR(M41)>
small M62 2
#ACT
ClearDelayGoto
MOV M62 0
MOV M45 2
MOV S23 大
GAMEGOLD - <$STR(M41)>
MOV M43 <$STR(M41)>
INC G13 <$STR(M43)>
SendMSG 4 %s使用<$STR(M41)>个元宝下注押大。
GOTO @MAIN
MESSAGEBOX [提示]：使用【<$STR(M41)>】个元宝下注押大。
MOV M41 0
BREAK
#IF
CHECKGAMEGOLD ? <$STR(M41)>
#ACT
DEC M62 1
SendMSG 5 [提示]：使用【<$STR(M41)>】个元宝下注押大，将在【<$STR(M62)>】秒后开始执行。
DelayCall 1000 ~InPutInteger41
BREAK
#say
美女庄家正在为您下注，请稍等。。。\
#ELSEACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV M41 0
GOTO @MAIN
BREAK
[@@InPutInteger42]
#If
CheckLevelEx > 0
#Act
MOVR M62 4
INC M62 2
DelayGoto 1 ~InPutInteger42
[~InPutInteger42]
#IF
LARGE G12 120
#ACT
MESSAGEBOX [提示]：下注时间已经结束。请等待开局！
MOV M42 0
GOTO @MAIN
BREAK
#IF
SMALL G12 61
#ACT
MESSAGEBOX [提示]：下注时间还没到，现在是抢庄时间。
MOV M42 0
GOTO @MAIN
BREAK
#IF
SMALL M42 10
#ACT
MESSAGEBOX [提示]：请输入10以上的数值！
MOV M42 0
GOTO @MAIN
BREAK
#IF
EQUAL A34 <$USERNAME>
#ACT
MOV M40 0
MESSAGEBOX [提示]：你目前已经是庄家，无法重复坐庄。
GOTO @MAIN
BREAK
#IF
EQUAL M45 2
#ACT
MOV M42 0
MESSAGEBOX [提示]：你已经下注押了大，无法重复下注！
GOTO @MAIN
BREAK
#IF
EQUAL M45 3
#ACT
MOV M42 0
MESSAGEBOX [提示]：你已经下注押了小，无法重复下注！
GOTO @MAIN
BREAK
#IF
LARGE M42 <$STR(G10)>
#ACT
MOV M42 0
MESSAGEBOX [提示]：对不起，庄家的本钱已达到上限不够赔了。\ \目前你只可以下注【<$STR(G10)>】以下的元宝！
GOTO @MAIN
BREAK
#IF
CHECKGAMEGOLD > <$STR(M42)>
small M62 2
#ACT
ClearDelayGoto
MOV M62 0
MOV M45 3
MOV S23 小
GAMEGOLD - <$STR(M42)>
MOV M43 <$STR(M42)>
INC G14 <$STR(M43)>
SendMSG 4 %s使用<$STR(M42)>个元宝下注押小。
GOTO @MAIN
MESSAGEBOX [提示]：使用【<$STR(M42)>】个元宝下注押小。
MOV M42 0
BREAK
#IF
CHECKGAMEGOLD ? <$STR(M42)>
#ACT
DEC M62 1
SendMSG 5 [提示]：使用【<$STR(M42)>】个元宝下注押小，将在【<$STR(M62)>】秒后开始执行。
DelayCall 1000 ~InPutInteger42
BREAK
#say
美女庄家正在为您下注，请稍等。。。\
#ELSEACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV M42 0
GOTO @MAIN
BREAK
[@Over]
#IF
#ACT
MapMove 3 330 330
BREAK
[@Help]
1)庄家坐庄后，其他玩家可下注，两分钟后三个骰子随机出现，点\
数总和小于11代表小，点数总和大于10代表大，三个点数相同代\
表豹子。\
2)押大赢大，押小赢小，豹子通吃，系统每次收取5%税务。\
3)正在坐庄或已下注的玩家如下线将被视做弃权，损失下注元宝。\
4)玩家下注数不能超过庄家坐庄的元宝总和。\
<返回/@MAIN> <离开/@EXIT>\
完整脚本下载地址：
页:
[1]